Acentuação no Sort do DataGrid

package sort
{
import mx.collections.SortField;
import mx.utils.ObjectUtil;
import mx.core.mx_internal;

use namespace mx_internal;

public class ExtendedSortField extends SortField
{

override mx_internal function initCompare(obj:Object):void
{
var isStringField:Boolean = false;

// if the compare function is not already set then we can set it
if (!usingCustomCompareFunction)
{
if (!numeric)
{
if (caseInsensitive)
isStringField = true;
else
{
// we need to introspect the data a little bit
var value:Object;
if (name)
{
try
{
value = obj[name];
}
catch (error:Error)
{
}
}
//this needs to be an == null check because !value will return true
//where value == 0 or value == false
if (value == null)
{
value = obj;
}

var typ:String = typeof(value);
switch (typ)
{
case "string":
isStringField = true;
break;
case "object":
if (!(value is Date))
{
isStringField = true;
var test:String;
try
{
test = value.toString();
}
catch (error2:Error) {}
if (!test || test == "[object Object]")
{
isStringField = false;
}
}
break;
}
}  // else
}
} // if

if (isStringField)
{
compareFunction = stringCompare;
}

super.initCompare(obj);
}

/**
* Pull the strings from the objects and call the implementation.
*/
private function stringCompare(a:Object, b:Object):int
{
var fa:String;
try
{
fa = name == null ? String(a) : String(a[name]);
}
catch (error:Error)
{
}

var fb:String;
try
{
fb = name == null ? String(b) : String(b[name]);
}
catch (error:Error)
{
}

var sa:String = "";
if (fa != null)
{
sa = String(mx.utils.ObjectUtil.copy(fa));
sa = removeSpecialChars(sa);
}

var sb:String = "";
if (fb != null)
{
sb = String(mx.utils.ObjectUtil.copy(fb));
sb = removeSpecialChars(sb);
}

return mx.utils.ObjectUtil.stringCompare(sa, sb, caseInsensitive);
}

/**
*
* @param value String de entrada que será modificada de acorde com a tabela ASCII extendida
* @return String alterada
*
*/
public static function removeSpecialChars(value:String):String
{
var patternTable:Object = new Object();
patternTable["A"] = /À|Á|Â|Ã|Ä|Å/g;
patternTable["E"] = /È|É|Ê|Ë/g;
patternTable["I"] = /Ì|Í|Î|Ï/g;
patternTable["O"] = /Ò|Ó|Ô|Õ|Ö/g;
patternTable["U"] = /Ù|Ú|Û|Ü/g;
patternTable["a"] = /à|á|â|ã|ä/g;
patternTable["e"] = /è|é|ê|ë/g;
patternTable["i"] = /ì|í|î|ï/g;
patternTable["o"] = /ò|ó|ô|õ|ö/g;
patternTable["u"] = /ù|ú|û|ü/g;
patternTable["C"] = /Ç/g;
patternTable["c"] = /ç/g;
patternTable["N"] = /Ñ/g;
patternTable["n"] = /ñ/g;

var result:String = value;
for (var letter:String in patternTable)
{
result = result.replace(patternTable[letter], letter);
}
return result;
}
}
}

public function ExtendedDataGrid()
{
// Como o listener foi criado com a mesma prioridade do listener da classe mãe,
// este deve ser adicionado ANTES da adição do mesmo da classe mãe,
// para que esta implementação seja executada da mesma forma, ANTES.
addEventListener(DataGridEvent.HEADER_RELEASE,
headerReleaseHandler,
false, EventPriority.DEFAULT_HANDLER, true);

super();
}

private function headerReleaseHandler(event:DataGridEvent):void
{
if (!event.isDefaultPrevented())
{
prepareGridColumnSort(this, dataProvider as ICollectionView,

event.dataField, !sortCaseSensitive);
}
}

/**
*
* @param grid Instância do DataGrid que será preparado para utilização do   caseInsensitive e Numeric
* @param gridDataProvider DataProvider do DataGrid, que será observado para criação da classe Sort
* @return DataProvider modificado, contendo a classe Sort e SortField definida para cada DataGridColumn do DataGrid
*
*/
private function prepareGridColumnSort(grid:DataGrid,    gridDataProvider:ICollectionView, dataField:String, caseInsensitive:Boolean=true):void
{
var sort:Sort;
var field:SortField;
var column:DataGridColumn;
var bFieldFound:Boolean = false;

if (gridDataProvider && dataField)
{
sort = gridDataProvider.sort;

if (sort == null)
{
sort = new Sort();
}

for each (field in sort.fields)
{
if (field.name == dataField)
{
field.caseInsensitive = caseInsensitive;
bFieldFound = true;
break;
}
}

if (!bFieldFound)
{
for each (column in grid.columns)
{
if (dataField == column.dataField)
{
field = new ExtendedSortField();
field.name = column.dataField;
field.descending = column.sortDescending;
field.caseInsensitive = caseInsensitive;
if (column.sortCompareFunction != null)
{
field.compareFunction = column.sortCompareFunction;
}
field.numeric = isDataFieldNumber(gridDataProvider, dataField);
sort.fields = [field];
break;
}
}
}

gridDataProvider.sort = sort;
}
}

/**
*
* @param gridDataProvider Instância do DataGrid no qual será testado o campo do tipo Number
* @param dataField Nome do campo que será testado
* @return Resultado boolean indicando se é Number ou não
*
*/
private function isDataFieldNumber(gridDataProvider:ICollectionView, dataField:String):Boolean
{
if (gridDataProvider && gridDataProvider.length  > 0 && dataField)
{
var obj:Object = gridDataProvider[0];
if (obj.hasOwnProperty(dataField) && ((obj[dataField] is Number) || (obj[dataField] is uint) || (obj[dataField] is int)))
{
return true;
}
}
return false;
}